git-proxy-java/build.gradle at main · coopernetes/git-proxy-java · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
plugins {
    id 'com.diffplug.spotless' version '8.4.0' apply false
    id 'org.owasp.dependencycheck' version '12.2.0'
    id 'org.cyclonedx.bom' version '3.2.4'
    id 'com.github.node-gradle.node' version '7.1.0' apply false
}

ext {
    // Tooling
    palantirJavaFormatVersion = '2.90.0'

    // JGit
    jgitVersion = '7.6.0.202603022253-r'

    // HTTP
    apacheHttpClientVersion = '5.6'

    // Jetty / Servlet
    jettyVersion = '12.1.8'
    jakartaServletVersion = '6.1.0'

    // Logging
    slf4jVersion = '2.0.17'
    log4j2Version = '2.25.4'

    // Database
    hikariVersion = '7.0.2'
    h2Version = '2.4.240'
    postgresVersion = '42.7.10'
    mongoVersion = '5.6.4'

    // Jackson
    jacksonBomVersion = '3.1.1'
    jacksonLegacyBomVersion = '2.18.6'

    // Spring
    springVersion = '7.0.6'
    springSecurityVersion = '7.0.4'
    springSessionVersion = '4.0.2'

    // YAML
    snakeyamlVersion = '2.2'

    // Gestalt config
    gestaltVersion = '0.37.2'

    // BouncyCastle
    bouncyCastleVersion = '1.83'

    // Commons
    commonsValidatorVersion = '1.10.1'

    // Lombok
    lombokVersion = '1.18.44'

    // Testing
    junitVersion = '5.14.3'
    junitPlatformVersion = '1.14.3'
    mockitoVersion = '5.17.0'
    testContainersVersion = '2.0.4'

    // Gitleaks (bundled binary)
    gitleaksVersion = '8.21.2'

    // OpenAPI spec generation
    swaggerCoreVersion = '2.2.48'
    swaggerUiVersion = '5.21.0'

}

allprojects {
    group = 'org.finos.gitproxy'
    version = '1.0.0-beta.5'

    repositories {
        mavenCentral()
        maven {
            url = 'https://repo.eclipse.org/content/groups/releases/'
        }
    }
    dependencyCheck {
        nvd.apiKey = System.getenv("NVD_API_KEY")
        analyzers.ossIndex.username = System.getenv("OSS_INDEX_USERNAME")
        analyzers.ossIndex.password = System.getenv("OSS_INDEX_TOKEN")
        analyzers.ossIndex.url = 'https://api.guide.sonatype.com/'
        failBuildOnCVSS = 5
        suppressionFile = rootProject.file('gradle-suppressions.xml').toString()
        failOnError = false
    }
}


cyclonedxBom {
    projectType = 'application'
}

tasks.register('installGitHooks') {
    group = 'build setup'
    description = 'Configures git to use the .githooks/ directory (run once after cloning).'
    doLast {
        ['git', 'config', 'core.hooksPath', '.githooks'].execute(null, rootDir).waitFor()
        println 'Git hooks installed — .githooks/pre-commit will run spotlessApply before each commit.'
    }
}

subprojects {
    apply plugin: 'com.diffplug.spotless'
    apply plugin: 'jacoco-report-aggregation'

    spotless {
        java {
            palantirJavaFormat("${palantirJavaFormatVersion}").formatJavadoc(true)
        }
    }

    plugins.withId('java') {
        apply plugin: 'jacoco'

        jacocoTestReport {
            dependsOn test
            reports {
                xml.required = true
                html.required = true
            }
        }

        test {
            finalizedBy jacocoTestReport
        }
    }
}