partout/CMakeLists.txt at master · partout-io/partout · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
cmake_minimum_required(VERSION 3.28)
if(POLICY CMP0157)
    cmake_policy(SET CMP0157 NEW)
endif()
project(Partout LANGUAGES Swift C CXX)
include(ExternalProject)
include(FetchContent)

# Command line options
option(PP_BUILD_LIBRARY "Include main library" 0)
option(PP_BUILD_USE_OPENSSL "Use OpenSSL" 0)
option(PP_BUILD_USE_MBEDTLS "Use MbedTLS" 0)
option(PP_BUILD_USE_OPENVPN "Use OpenVPN" 0)
option(PP_BUILD_USE_WIREGUARD "Use WireGuard" 0)

# Output per platform/arch
string(TOLOWER ${CMAKE_SYSTEM_NAME} PLATFORM_NAME)
string(TOLOWER ${CMAKE_SYSTEM_PROCESSOR} ARCH_NAME)
if(DEFINED PP_BUILD_OUTPUT)
    set(PP_BUILD_OUTPUT_UNIVERSAL "${PP_BUILD_OUTPUT}")
else()
    set(PP_BUILD_OUTPUT_UNIVERSAL "${CMAKE_CURRENT_SOURCE_DIR}/bin")
    set(PP_BUILD_OUTPUT "${PP_BUILD_OUTPUT_UNIVERSAL}/${PLATFORM_NAME}-${ARCH_NAME}")
endif()

# Options
message(STATUS "Option CMAKE_BUILD_TYPE = ${CMAKE_BUILD_TYPE}")
message(STATUS "Option PP_BUILD_LIBRARY = ${PP_BUILD_LIBRARY}")
message(STATUS "Option PP_BUILD_USE_OPENSSL = ${PP_BUILD_USE_OPENSSL}")
message(STATUS "Option PP_BUILD_USE_MBEDTLS = ${PP_BUILD_USE_MBEDTLS}")
message(STATUS "Option PP_BUILD_USE_OPENVPN = ${PP_BUILD_USE_OPENVPN}")
message(STATUS "Option PP_BUILD_USE_WIREGUARD = ${PP_BUILD_USE_WIREGUARD}")
message(STATUS "Option PP_BUILD_OUTPUT = ${PP_BUILD_OUTPUT}")

# All vendor-inherited args
if(WIN32)
    set(MAKE_CMD nmake)
else()
    set(MAKE_CMD make)
endif()
set(LIBEXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
set(LIBEXT_STATIC ${CMAKE_STATIC_LIBRARY_SUFFIX})
set(LIBEXT_IMP ${CMAKE_IMPORT_LIBRARY_SUFFIX})
set(LIBPFX_STATIC ${CMAKE_STATIC_LIBRARY_PREFIX})

# Define VENDOR_ENV to prepend NDK toolchain on Android
if(DEFINED ANDROID_TOOLCHAIN_ROOT)
    if(CMAKE_HOST_WIN32)
        set(VENDOR_PATH "${ANDROID_TOOLCHAIN_ROOT}/bin;$ENV{PATH}")
        string(REPLACE ";" "\\;" VENDOR_PATH "${VENDOR_PATH}")
    else()
        set(VENDOR_PATH "${ANDROID_TOOLCHAIN_ROOT}/bin:$ENV{PATH}")
    endif()
    set(VENDOR_ENV ${CMAKE_COMMAND} -E env PATH=${VENDOR_PATH} ANDROID_NDK_ROOT=$ENV{ANDROID_NDK_HOME})
endif()

if(PP_BUILD_USE_OPENSSL)
    include("vendors/openssl.cmake")
elseif(PP_BUILD_USE_MBEDTLS)
    include("vendors/mbedtls.cmake")
endif()
if(PP_BUILD_USE_WIREGUARD)
    include("vendors/wg-go.cmake")
endif()

# Fetch wintun.dll on Windows
if(WIN32)
    set(WINTUN_VERSION "0.14.1")
    include("vendors/wintun.cmake")
endif()

# Build Partout library (opt-in), after vendored dependencies
if(PP_BUILD_LIBRARY)
    add_subdirectory(Sources)
    if(PP_BUILD_USE_OPENSSL)
        target_link_libraries(partout_c PUBLIC OpenSSLInterface)
    elseif(PP_BUILD_USE_MBEDTLS)
        target_link_libraries(partout_c PUBLIC MbedTLSInterface)
    endif()
    if(PP_BUILD_USE_WIREGUARD)
        target_link_libraries(partout_c PUBLIC WireGuardGoInterface)
    endif()
endif()